begintownscript;
variables;
short choice,i;

body;
beginstate init_state;
i = 0;
while(char_ok(i) == 0){
	i = i + 1;
}
message_dialog("It wasn't hard to follow Half-Axe and his men's trail. They were careless-- confident of escaping retribution for their deeds. Bandits walk these woods like they own them-- there's nobody to argue.","The trail took me back to their hideout. It was nothing so romantic-- just a shantytown in the middle of the woods, nearly in the shadow of the walls of Cigosal itself.");
	message_dialog("It wasn't a far travel, which only served to add fuel to the fire of my anger. They were right here, just a few miles from the Chapel. It was my duty to watch these woods, and I had not even noticed them.","");
set_character_facing(i,0);
force_instant_terrain_redraw();
break;

beginstate exit_state;
break;

beginstate start_state;
if((num_chars_in_group(1) == 0) && (get_flag(6,1) == 0)){
	set_flag(6,1,1);
	reset_dialog();
	add_dialog_str(0,"The last of the bandits fell dead. They were not men of the sword, they were peasants who turned to preying on their fellow man when times got hard.",0);
	add_dialog_str(1,"They came home at night with the fruits of other men's toils and fed their families. Their wives cowered in their pathetic shanties and listened to their men die; all because they wouldn't make it on their own work-- or couldn't.",0);
	add_dialog_str(2,"It was almost pitiful.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
}
break;

beginstate 10;
if(get_flag(6,0) == 0){
	set_flag(6,0,1);
	set_attitude(1001,10);
	message_dialog("The brigands were gathered around a bon fire in the center of their shantytown, celebrating with a cask of wine and a crate of dried fruit stolen from the Chapel.","They didn't have to steal it-- the Order gives away everything they have to those that need it-- it was just senseless.");
	message_dialog("They hadn't set a guard-- didn't need to, there's nobody out there to challenge them-- and didn't notice my presence until I was standing in the light of the campfire. One of them demanded I identify myself.","I told him I was here to see Half-Axe. That I had a score to settle with him and that standing between us would be a death sentence. He spit into the fire and laughed as he drew a curved scimitar-- big mistake.");
}
break;

beginstate 11;
if(get_flag(6,2) == 0){
	message_dialog("Half-Axe's home was a tall wooden structure, a palace compared to the rest of this dump.","The brigand chief himself was much the same. An average man, only impressive because of the piteousness of the rest of his rabble. He wielded a large battle-axe, and unlike his fellows he seemed to at least know which end to hit people with.");
	set_flag(6,2,1);
	set_attitude(1002,10);
}
break;

beginstate 12;
if(get_flag(6,2) == 0)
	end();
block_entry(1);
if(get_flag(6,4) == 0)
	message_dialog("I wasn't going to leave until I found that star. Nobody would come in the way of my holy quest--  Half-Axe and his pathetic rabble were nuisances, nothing more.","");
else{
	set_character_facing(i,6);
	move_to_new_town(7,2,15);
}
break;

beginstate 13;
reset_dialog();
add_dialog_str(0,"Half-Axe was dead, slain by my hand. I wasn't satisfied really-- I don't know if I was expecting to be. The Blue Needles were rid of another band of these parasites, but I didn't feel like I'd accomplished anything.",0);
add_dialog_str(1,"I couldn't protect the Chapel. You can kill them all you want, but you won't save anything. It won't change anything-- there will always be more to take their place.",0);
add_dialog_str(2,"There will always be men who decide they'd rather steal than work, and I hate them for it.",0);
add_dialog_choice(0,"OK");
choice = run_dialog(1);
set_flag(6,3,1);
break;

beginstate 14;
if(get_flag(6,3) == 0)
	end();
if(get_flag(6,4) > 0)
	end();
reset_dialog();
add_dialog_str(0,"Half-Axe had his most impressive trophies hanging on the wall over his bed, but the star was not among them.",0);
add_dialog_str(1,"There was a box in the corner where he kept his trinkets, a chest of junk and chintzy tokens. That was where I found the star.",0);
add_dialog_str(2,"He knew it wasn't gold or anything valuable, just a bronze star with seven points for seven virtues. It wasn't worth hanging on the wall-- it was in the box of junk where it belonged.",0);
add_dialog_str(3,"I picked it up anyway. It meant something at some point.",0);
add_dialog_choice(0,"OK");
choice = run_dialog(1);
change_spec_item(0,1);
set_flag(6,4,1);
break;

beginstate 100;
block_entry(1);
break;

beginstate 101;
block_entry(1);
message_dialog("I'd come to find this Half-Axe and deliver justice, not to search through the filthy holes that these bandits call homes.","");
break;